Tools:WinXP-Offline-Update

Allgemeines

Alle PCs sollten immer mit aktuellen Updates für WinXP und Office versorgt werden. Die automatische Aktualisierung von WinXP stört ggf. den Unterricht und meckert evtl. über einen fehlenden Internet-Zugang. Die Office-Aktualisierung ist (meiner Meinung nach) nur von Hand auf jedem PC möglich.

Mit Hilfe des c’t-Projekts „ctupdate4“ können alle Updates von einem XP-PC mit permanentem Internetzugang (z.B. Lehrerzimmer oder Sekretariat) auf Arktur herunter geladen werden. Die PCs holen sich dann die Updates über eine automatische Task beim Starten des PCs, da diese mit Admin-Rechte gestartet werden kann (auch wenn der User nur Benutzer ist).

Vorbereitungen auf Arktur

• Als adm von einem PC aus das Serververzeichnis für Update-Dateien anlegen (z.B. \\Arktur\pub\software\XP-Update ).
• Aktuelle Version von ctupdate von http://www.heise.de/ct/projekte/offlineupdate herunterladen, in das Verzeichnis kopieren und dort entpacken, so dass darin das Verzeichnis ctupdate4 mit Unterstrukturen angelegt wird.
• Gewünschte Updates einmal von Hand herunterladen. Dazu das Download-Programm \\Arktur\pub\software\XP-Update\ctupdate4\UpdateGenerator.exe von Hand starten.

Auf der Karte Office-Pakete das passende Office-Paket (z.B. Office2000) ankreuzen und runterladen.

Die folgenden zwei Batch-Dateien erleichtern die automatische Aktualisierung. Das Download-Skript erzeugt drei kleine Log-Dateien gleichen Verzeichnis, um Informationen über den letzten Download zur Verfügung zu haben. Das Update-Skript erzeugt eine kleine Log-Datei Computername_LastUpdated_WinXP_O2k.txt auf C:\ und kopiert diese zum Schluß auch in das Verzeichnis \\Arktur\pub\software\XP-Update, damit man dort den Überblick hat, welche PCs wann mit welchem Stand aktualisiert wurden. Beide Skripte erzeugen ein temporäres Mapping des Verzeichnisses \\Arktur\pub\software\XP-Update auf das Laufwerk Z:, da ctupdate-Skripte nur über Laufwerkbuchstaben funktionieren.

• Die zwei Dateien bitte im Verzeichnis \\Arktur\pub\software\XP-Update anlegen.

XP_O2k_Download.cmd

rem Download von Updates fuer Win XP und Office 2000

cls

rem +++++++++ Definitionen +++++++++++++++
rem Freies Laufwerk fuer temporaeres Mapping (einige Skripte laufen nicht über Server-Pfade wie \\arktur\...)
set LW=Z:

rem Pfad auf Verzeichis, in dem sich das Verzeichnis ctupdate4 befindet
set ROOT=\\Arktur\pub\software\XP-Update

rem Namen der Log-Dateien
set SLOG=%ROOT%\DownloadSummary.txt
set XLOG=%ROOT%\DownloadDetailsWinXP.txt
set OLOG=%ROOT%\DownloadDetailsOffice.txt
rem ++++++++++++++++++++++++++++++++++++++ 

rem Sicherheitshabler ein evtl. bestehendes Mapping loeschen
IF EXIST %LW%\NUL net use %LW% /delete /YES
echo Serverpfad auf Laufwerkbuchstaben legen
net use %LW% %ROOT% /PERSISTENT:NO /YES

echo Start of downloads > %SLOG%
date /T >> %SLOG%
time /T >> %SLOG%
echo. >> %SLOG%

echo.
echo Download WinXP-Updates 

echo Errorlevel vor WinXP-Download: %ERRORLEVEL% >> %SLOG%
call %LW%\ctupdate4\cmd\DownloadUpdates.cmd wxp deu /proxy http://192.168.0.1:8080 > %XLOG%
echo Errorlevel nach WinXP-Download: %ERRORLEVEL% >> %SLOG%

echo.
echo Download Office2000-Updates

echo Errorlevel vor Office-Download: %ERRORLEVEL% >> %SLOG%
call %LW%\ctupdate4\cmd\DownloadUpdates.cmd o2k deu /proxy http://192.168.0.1:8080 > %OLOG%
echo Errorlevel nach Office-Download: %ERRORLEVEL% >> %SLOG%

echo.

echo. >> %SLOG%
echo End of downloads >> %SLOG%
date /T >> %SLOG%
time /T >> %SLOG%

echo Temporaeres Laufwerk-Mapping wieder loeschen
net use %LW% /delete /YES

XP_O2k_Update.cmd

rem Einspielen der Updates von Win XP und Office 2000

cls

rem +++++++++ Definitionen +++++++++++++++
rem Freies Laufwerk fuer temporaeres Mapping (einige Skripte laufen nicht über Server-Pfade wie \\arktur\...)
set LW=Z:

rem Pfad auf Verzeichis, in dem sich das Verzeichnis ctupdate4 befindet
set ROOT=\\Arktur\pub\software\XP-Update

rem Namen der Log-Dateien
set LOGNAME=%COMPUTERNAME%_LastUpdated_WinXP_O2k.txt
set LOCALLOG=C:\%LOGNAME%
rem ++++++++++++++++++++++++++++++++++++++

rem Sicherheitshabler ein evtl. bestehendes Mapping loeschen
IF EXIST %LW%\NUL net use %LW% /delete /YES
echo Serverpfad auf Laufwerkbuchstaben legen
net use %LW% %ROOT% /PERSISTENT:NO /YES 

echo Start Updating ... > %LOCALLOG%
date /T >> %LOCALLOG%
time /T >> %LOCALLOG%

echo. >> %LOCALLOG%
echo Build date of updates >> %LOCALLOG%
type %LW%\ctupdate4\client\builddate.txt >> %LOCALLOG%
echo. >> %LOCALLOG%
echo.
echo Updating WinXP und Office
echo Errorlevel vor Update: %ERRORLEVEL% >> %LOCALLOG%
call %LW%\ctupdate4\client\cmd\DoUpdate.cmd /nobackup
echo Errorlevel nach Update: %ERRORLEVEL% >> %LOCALLOG%
echo. >> %LOCALLOG%
echo ... End Updating >> %LOCALLOG%
date /T >> %LOCALLOG%
time /T >> %LOCALLOG%

echo.
echo Kopie der Log-Datei auch auf dem Server ablegen
copy /Y %LOCALLOG% %LW%\%LOGNAME%

echo Temporaeres Laufwerk-Mapping wieder loeschen
net use %LW% /delete /YES

Vorbereitungen auf dem PC

• Auf allen PCs das Updaten als Task mit Admin-Rechten einrichten.

Start – Programme – Zubehör – Systemprogramme – Geplante Tasks 
Geplanten Task hinzufügen – Weiter – Durchsuchen - \\Arktur\pub\software\XP-Update\XP_O2k_Update.cmd auswählen
Task ausführen = Beim Starten des Computers
Benutzername = SCHULE\adm, Passwort = ???, Passwort = ???
Erweiterte Eigenschaften bei Fertigstellen = nein, Fertigstellen

• Einen häufig benutzten PC mit (möglichst) permanentem Internetzugang als „Downloader“ einrichten.

Start – Programme – Zubehör – Systemprogramme – Geplante Tasks 
Geplanten Task hinzufügen – Weiter – Durchsuchen - \\Arktur\pub\software\XP-Update\XP_O2k_Download.cmd auswählen
Task ausführen = Beim Starten des Computers
Benutzername = SCHULE\adm, Passwort = ???, Passwort = ???
Erweiterte Eigenschaften bei Fertigstellen = nein, Fertigstellen

• Wie man die Update-Task elegant auf alle Rechner überträgt (ohne eine neues Image einzuspielen), Ideen sind noch jederzeit willkommen.
• Falls sich die zwei Tasks auf dem Download-PC gegenseitig stören: Die Download-Task zeitgesteuert starten lassen, wenn der PC normalerweise schon länger im Betrieb ist oder nachts den PC aufwachen lassen und den Download durchführen. Dazu muss Arktur aber auch per crontab den Internetzugang geöffnet haben.

Betrieb

• Der Download-PC holt automatisch die Updates und legt sich mit SCHULE\adm-Rechten im angegebenen Verzeichnis ab.
• Jeder PC holt sich automatisch beim Starten die neusten, auf Arktur verfügbaren Updates (ohne dass eine Internet-Verbindung bestehen muss). Auf PCs mit sehr veraltetem Update-Stand könnte es vorkommen, dass der PC neu gebootet werden muss oder andere manuelle Eingaben notwendig sein. Wie das Skript dann reagiert, kann ich hier nicht mehr testen, dafür bin ich auf zu neuem Stand. Eigentlich müsste das Update einfach beim nächsten Starten mit den folgenden Updates weitermachen.